annotate contrib/nix/flake.nix @ 51580:b70628a9aa7e

phases: use revision number in new_heads

All graph operations will be done using revision numbers, so passing nodes only
means they will eventually get converted to revision numbers internally.

As part of an effort to align the code on using revision number we make the
`phases.newheads` function operated on revision number, taking them as input
and using them in returns, instead of the node-id it used to consume and
produce.

This is part of multiple changesets effort to translate more part of the logic,
but is done step by step to facilitate the identification of issue that might
arise in mercurial core and extensions.

To make the change simpler to handle for third party extensions, we also rename
the function, using a more modern form. This will help detecting the different
between the node-id version and the rev-num version.

I also take this as an opportunity to add some comment about possible
performance improvement for the future. They don't matter too much now, but they
are worse exploring in a while.

# flake.nix - Nix-defined package and devel env for the Mercurial project.
#
# Copyright 2021-2023 Pacien TRAN-GIRARD <[e-mail]>
#
# This software may be used and distributed according to the terms of the
# GNU General Public License version 2 or any later version.

# Usage summary, from the root of this repository:
#
# Enter a shell with development tools:
#   nix develop 'hg+file:.?dir=contrib/nix'
#
# Running mercurial:
#   nix run 'hg+file:.?dir=contrib/nix' -- version
#
# Running the test suite in a sandbox:
#   nix build 'hg+file:.?dir=contrib/nix#mercurial-tests' -L

{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-22.11";
    nixpkgs-black.url = "github:NixOS/nixpkgs/c7cb72b0";  # black 20.8b1
    # rust-overlay.url = "github:oxalica/rust-overlay";
    flake-utils.url = "github:numtide/flake-utils";
    flaky-utils.url = "git+https://cgit.pacien.net/libs/flaky-utils";
  };

  outputs = {
    self
  , nixpkgs
  , nixpkgs-black
  # , rust-overlay
  , flake-utils
  , flaky-utils
  }:
  flake-utils.lib.eachDefaultSystem (system:
  let
    # overlays = [ (import rust-overlay) ];
    pkgs = import nixpkgs { inherit system; };

    # We're in the contrib/nix sub-directory.
    src = ../..;

    # For snapshots, to satisfy extension minimum version requirements.
    dummyVersion = "99.99";

    pin = {
      # The test suite has issues with the latest/current versions of Python.
      # Use an older recommended version instead, matching the CI.
      python = pkgs.python39;

      # The project uses a pinned version (rust/clippy.toml) for compiling,
      # but uses formatter features from nightly.
      # TODO: make cargo use the formatter from nightly automatically
      #       (not supported by rustup/cargo yet? workaround?)
      # rustPlatform = pkgs.rust-bin.stable."1.61.0".default;
      # rustPlatformFormatter = pkgs.rust-bin.nightly."2023-04-20".default;

      # The CI uses an old version of the Black code formatter,
      # itself depending on old Python libraries.
      # The formatting rules have changed in more recent versions.
      inherit (import nixpkgs-black { inherit system; }) black;
    };

  in rec {
    apps.mercurial = apps.mercurial-rust;
    apps.default = apps.mercurial;
    apps.mercurial-c = flake-utils.lib.mkApp {
      drv = packages.mercurial-c;
    };
    apps.mercurial-rust = flake-utils.lib.mkApp {
      drv = packages.mercurial-rust;
    };

    packages.mercurial = packages.mercurial-rust;
    packages.default = packages.mercurial;

    packages.mercurial-c = pin.python.pkgs.buildPythonApplication {
      format = "other";
      pname = "mercurial";
      version = "SNAPSHOT";
      passthru.exePath = "/bin/hg";
      inherit src;

      postPatch = ''
        echo 'version = b"${toString dummyVersion}"' \
          > mercurial/__version__.py

        patchShebangs .

        for f in **/*.{py,c,t}; do
          # not only used in shebangs
          substituteAllInPlace "$f" '/bin/sh' '${pkgs.stdenv.shell}'
        done
      '';

      buildInputs = with pin.python.pkgs; [
        docutils
      ];

      nativeBuildInputs = with pkgs; [
        gettext
        installShellFiles
      ];

      makeFlags = [
        "PREFIX=$(out)"
      ];

      buildPhase = ''
        make local
      '';

      # Test suite is huge ; run on-demand in a separate package instead.
      doCheck = false;
    };

    packages.mercurial-rust = packages.mercurial-c.overrideAttrs (super: {
      cargoRoot = "rust";
      cargoDeps = pkgs.rustPlatform.importCargoLock {
        lockFile = "${src}/rust/Cargo.lock";
      };

      nativeBuildInputs = (super.nativeBuildInputs or []) ++ (
        with pkgs.rustPlatform; [
          cargoSetupHook
          rust.cargo
          rust.rustc
        ]
      );

      makeFlags = (super.makeFlags or []) ++ [
        "PURE=--rust"
      ];
    });

    packages.mercurial-tests = pkgs.stdenv.mkDerivation {
      pname = "mercurial-tests";
      version = "SNAPSHOT";
      inherit src;

      buildInputs = with pkgs; [
        pin.python
        pin.black
        unzip
        which
        sqlite
      ];

      postPatch = (packages.mercurial.postPatch or "") + ''
        # * paths emitted by our wrapped hg look like ..hg-wrapped-wrapped
        # * 'hg' is a wrapper; don't run using python directly
        for f in **/*.t; do
          substituteInPlace 2>/dev/null "$f" \
            --replace '*/hg:' '*/*hg*:' \
            --replace '"$PYTHON" "$BINDIR"/hg' '"$BINDIR"/hg'
        done
      '';

      buildPhase = ''
        export HGTEST_REAL_HG="${packages.mercurial}/bin/hg"
        export HGMODULEPOLICY="rust+c"
        export HGTESTFLAGS="--blacklist blacklists/nix"
        make check 2>&1 | tee "$out"
      '';
    };

    devShell = flaky-utils.lib.mkDevShell {
      inherit pkgs;

      tools = [
        pin.python
        pin.black
      ];
    };
  });
}